Si toi aussi tu commandes ton matos sur aliexpress ou équivalent tu as surement vu cette petite lampe en forme de lune qui fait bien dans ton intérieur scandinave 😆 En écrivant ces lignes j'ai vu qu'à présent elle existe en RGB avec télécommande ... la mienne est juste capable de donner différents blancs.

[upl-image-preview uuid=dc0e2add-b264-4172-917f-6b7d22423404 url=https://forum.caliban.be/assets/files/2026-04-11/1775939356-981201-blue.png alt={TEXT?}]
Comme c'est une bonne chinoiserie ma belle lampe est rapidement tombée en panne :?
En bon bidouilleur j'ai ouvert la bête pour la réparer ... mais non, ce sont les leds qui ont cramées.

Tant mieux je vais en profiter pour l'upgader :lol:
Un ESP32, un ring Neopixel et un MPU6050 il n'en faut pas plus pour s'amuser 😃

Le fonctionnement

Le bouton poussoir du dessous permet de sortir l'ESP32 du sommeil ou de l'y plonger.
La lampe s'allume dans un des modes programmé, j'en ai fait 4, blanc chaud, froid, rainbow et un rainbow qui varie quand on bouge la sphère.
Une tape sur la lune permet de passer d'un mode à l’autre. Pour indiquer le changement de mode la lune clignote.
La lune se replonge en Deep Sleep après 30 minutes.

Le matériel

J'ai fait mes fonds de tiroirs.
J'ai utilisé un Wemos Lolin32 qui a l'avantage de disposer d'un circuit de charge pour une batterie lipo 1s
Une batterie lipo 1S de 1000mAh qui se loge parfaitement entre les pattes de l'esp32 et se branche sur le connecteur de la Lolin32.
Un ring de 8 neopixels, branché sur le 3.3v et la pin 23 de la Lolin32. Ca donne bien.
Un MPU6050 pour détecter les inclinaisons et chocs. SDA branché sur 21 et SCL à 22 de l'esp. J'ai branché le VCC du MPU sur la pin 19 de l'ESP32.
Ainsi quand l'ESP se met en deep sleep le MPU6050 est coupé et ne consomme pas d'énergie pour préserver la batterie.
Un bouton poussoir car celui d'origine n'a pas survécu au démontage. Connecté entre la pin 26 de l'esp et le GND
J'ai récupéré le connecteur d’alimentation d'origine qui est connecté au +5V de la lolin32
Beaucoup de colle chaude pour fixer le tout pour que ça ne bouge plus. J'en ai encore ajouté après avoir fait les photos.

[upl-image-preview uuid=92d4e470-a1ef-451a-84f7-806b60ee9c20 url=https://forum.caliban.be/assets/files/2026-04-11/1775939357-283092-green.png alt={TEXT?}] [upl-image-preview uuid=e1c541a6-eb9f-4b32-8412-1ea7a43bad68 url=https://forum.caliban.be/assets/files/2026-04-11/1775939358-190331-red.png alt={TEXT?}] [upl-image-preview uuid=b77e1233-e9db-4cce-83cc-d053516b55f6 url=https://forum.caliban.be/assets/files/2026-04-11/1775939358-469008-03.png alt={TEXT?}]

Le code
Je vais pas m'amuser à l'expliquer.
Il est assez basique. A noter qu'il permet de reprogrammer l'esp via wifi.
Il faudra donc modifier les lignes avec les identifiants de votre réseau wifi ligne 27-28 et éventuellement ceux de l'OTA ligne 53-54.
N'oublie pas d'intégrer les nombreuses librairies utilisées #include à l'ide arduino.
Tu peux bien sur utiliser ce code dans une lampe que tu aurais faite ou imprimée par exemple.

[upl-image-preview uuid=5679688e-ba97-4fb1-b7a0-05d9a9f408a8 url=https://forum.caliban.be/assets/files/2026-04-11/1775939359-187913-02.png alt={TEXT?}] [upl-image-preview uuid=0f6e524b-04fe-4816-a159-ee1a9f0c43c3 url=https://forum.caliban.be/assets/files/2026-04-11/1775939359-457719-01.png alt={TEXT?}] [upl-image-preview uuid=1faa6677-61bd-4c5f-8331-263cbc05b799 url=https://forum.caliban.be/assets/files/2026-04-11/1775939360-143930-capture-decran-2023-07-04-142628.png alt={TEXT?}]

/*   
MPU 650 SDA 21 - SCL 22 - VCC - 19
Neopixel 8X  23
BP 26-GND*/

#include <WiFi.h>
#include <ESPmDNS.h>
#include <WiFiUdp.h>
#include <ArduinoOTA.h>
#include "driver/rtc_io.h"
#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>
#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
#include <avr/power.h>
#endif

#define BUTTON_PIN_BITMASK 0x200000000  // 2^33 in hex
#define LED_PIN 23
#define LED_COUNT 8
Adafruit_NeoPixel strip(LED_COUNT, LED_PIN, NEO_GRB + NEO_KHZ800);

int MPU_EN = 19;
Adafruit_MPU6050 mpu;

const char* ssid = "XXX";
const char* password = "XXX";

float acc = 0;
float gyro = 0;
int seuil_acc = 100;
int count = 3;
int DelayAutoOff = 1800000;  //3600000
unsigned long previousTimeRainbow = 0;
unsigned long currentTime = 0;
unsigned long previousTime = 0;
int firstPixelHue = 0;
const int buttonPin = 26;
int buttonState = 1;


void setup(void) {
  Serial.begin(115200);
  delay(100);
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.waitForConnectResult() != WL_CONNECTED) {
    Serial.println("Connection Failed! Rebooting...");
    delay(5000);
    ESP.restart();
  }
  ArduinoOTA.setHostname("MOON");
  ArduinoOTA.setPassword("MOON");
  ArduinoOTA
    .onStart([]() {
      String type;
      if (ArduinoOTA.getCommand() == U_FLASH)
        type = "sketch";
      else
        type = "filesystem";
      Serial.println("Start updating " + type);
    })
    .onEnd([]() {
      Serial.println("\nEnd");
    })
    .onProgress([](unsigned int progress, unsigned int total) {
      Serial.printf("Progress: %u%%\r", (progress / (total / 100)));
    })
    .onError([](ota_error_t error) {
      Serial.printf("Error[%u]: ", error);
      if (error == OTA_AUTH_ERROR) Serial.println("Auth Failed");
      else if (error == OTA_BEGIN_ERROR) Serial.println("Begin Failed");
      else if (error == OTA_CONNECT_ERROR) Serial.println("Connect Failed");
      else if (error == OTA_RECEIVE_ERROR) Serial.println("Receive Failed");
      else if (error == OTA_END_ERROR) Serial.println("End Failed");
    });

  ArduinoOTA.begin();
  Serial.println("Ready");
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
  pinMode(buttonPin, INPUT_PULLUP);
  rtc_gpio_pullup_en(GPIO_NUM_26);
  esp_sleep_enable_ext0_wakeup(GPIO_NUM_26, 0);
  #if defined(__AVR_ATtiny85__) && (F_CPU == 16000000)
    clock_prescale_set(clock_div_1);
  #endif
  strip.begin();             // INITIALIZE NeoPixel strip object (REQUIRED)
  strip.show();              // Turn OFF all pixels ASAP
  strip.setBrightness(255);  // Set BRIGHTNESS to about 1/5 (max = 255)
  pinMode(MPU_EN, OUTPUT);
  digitalWrite(MPU_EN, HIGH);
  Serial.println("Adafruit MPU6050 test!");
  if (!mpu.begin()) {
    Serial.println("Failed to find MPU6050 chip");
    while (1) {
      delay(10);
    }
  }
  Serial.println("MPU6050 Found!");
  mpu.setAccelerometerRange(MPU6050_RANGE_16_G);
  mpu.setGyroRange(MPU6050_RANGE_2000_DEG);
  mpu.setFilterBandwidth(MPU6050_BAND_260_HZ);
  delay(100);
}

void loop() {

  ArduinoOTA.handle();
  buttonState = digitalRead(buttonPin);
  if (buttonState == LOW) {
    Serial.println("Go to Sleep");
    Blink();
    Sleep();
  }
  sensors_event_t a, g, temp;
  mpu.getEvent(&a, &g, &temp);
  acc = abs(a.acceleration.x + a.acceleration.y + a.acceleration.z);
  gyro = abs(g.gyro.x + g.gyro.y + g.gyro.z); 
  if (acc > seuil_acc) {
    count = count + 1;
    count %= 4;  // si count > 4 count = 0
    Serial.println(count);
    Blink();
    previousTime = currentTime;
  }
  currentTime = millis();
  switch (count) {
    case 0:
      { //Changement de couleur via gyroscope
        if (gyro > 1) {
          previousTime = currentTime;
          Rainbow();
        }
        break;
      }
    case 1:
      { //Changement de couleur progressive
        if ((currentTime - previousTimeRainbow) > 100) {
          previousTimeRainbow = currentTime;
          Rainbow();
        }
        break;
      }
    case 2:
      { //Blanc Froid
        colorWipe(strip.Color(255, 255, 255), 0); 
        break;
      }
    case 3:
      { //Blanc Chaud
        colorWipe(strip.Color(245, 127, 23), 0);
        break;
      }
      
  }
  if ((currentTime - previousTime) > DelayAutoOff) {
    Sleep();
  }
}
void colorWipe(uint32_t color, int wait) {
  for (int i = 0; i < strip.numPixels(); i++) {
    strip.setPixelColor(i, color);
    strip.show();
    delay(wait);
  }
}
void Rainbow() {
  for (int a = 0; a < 8; a++) {
    strip.setPixelColor(a, strip.gamma32(strip.ColorHSV(firstPixelHue)));  // Set pixel 'c' to value 'color'
  }
  firstPixelHue += 65536 / 360;
  firstPixelHue %= 65536;
  strip.show();
}

void Sleep() {
  colorWipe(strip.Color(0, 0, 0), 0);
  Serial.println("Going to sleep now");
  esp_deep_sleep_start();
}

void Blink() {
  colorWipe(strip.Color(255, 0, 0), 0);
  strip.show();
  delay(300);
  colorWipe(strip.Color(0, 255, 0), 0);
  strip.show();
  delay(300);
  colorWipe(strip.Color(0, 0, 2550), 0);
  strip.show();
  delay(300);
}